resource "google_compute_network" "vpc" {
  name                    = "${var.project_name}-vpc"
  auto_create_subnetworks = false
}


resource "google_compute_subnetwork" "frontend" {
  name          = "frontend"
  network       = google_compute_network.vpc.id
  ip_cidr_range = var.frontend_cidr
  region        = var.region
}


resource "google_compute_subnetwork" "backend" {
  name          = "backend"
  network       = google_compute_network.vpc.id
  ip_cidr_range = var.backend_cidr
  region        = var.region
}

resource "google_compute_subnetwork" "database" {
  name          = "database"
  network       = google_compute_network.vpc.id
  ip_cidr_range = var.database_cidr
  region        = var.region
}







resource "google_compute_firewall" "frontend_http_https" {
  name    = "${var.project_name}-frontend-http-https"
  network = google_compute_network.vpc.name

  allow {
    protocol = "tcp"
    ports    = ["80", "443"]
  }

  source_ranges = ["0.0.0.0/0"]

  target_tags = ["frontend"]
}



resource "google_compute_firewall" "ssh_access" {
  name    = "${var.project_name}-ssh"
  network = google_compute_network.vpc.name

  allow {
    protocol = "tcp"
    ports    = ["22"]
  }

  source_ranges = [var.ssh_source_ranges]

  target_tags = ["frontend", "backend", "database"]
}


resource "google_compute_firewall" "frontend_to_backend" {
  name    = "${var.project_name}-frontend-to-backend"
  network = google_compute_network.vpc.name

  allow {
    protocol = "tcp"
    ports    = ["8000"]
  }

  source_tags = ["frontend"]
  target_tags = ["backend"]
}


resource "google_compute_firewall" "backend_to_database" {
  name    = "${var.project_name}-backend-to-database"
  network = google_compute_network.vpc.name

  allow {
    protocol = "tcp"
    ports    = ["3306"]
  }

  source_tags = ["backend"]
  target_tags = ["database"]
}