resource "google_compute_network" "vpc" {
  name                    = "${var.project_name}-vpc"
  project                 = var.project_name
  auto_create_subnetworks = false
}

resource "google_compute_subnetwork" "frontend" {
  name          = "${var.project_name}-frontend-subnet"
  project       = var.project_name
  ip_cidr_range = var.frontend_cidr
  region        = var.region
  network       = google_compute_network.vpc.self_link
}

resource "google_compute_subnetwork" "backend" {
  name          = "${var.project_name}-backend-subnet"
  project       = var.project_name
  ip_cidr_range = var.backend_cidr
  region        = var.region
  network       = google_compute_network.vpc.self_link
}

resource "google_compute_subnetwork" "database" {
  name          = "${var.project_name}-database-subnet"
  project       = var.project_name
  ip_cidr_range = var.database_cidr
  region        = var.region
  network       = google_compute_network.vpc.self_link
}

resource "google_compute_firewall" "fw_http_https_frontend" {
  name    = "${var.project_name}-fw-http-https-frontend"
  project = var.project_name
  network = google_compute_network.vpc.name

  direction = "INGRESS"

  source_ranges = ["0.0.0.0/0"]

  target_tags = ["frontend"]

  allow {
    protocol = "tcp"
    ports    = ["80", "443"]
  }
}

resource "google_compute_firewall" "fw_ssh" {
  name    = "${var.project_name}-fw-ssh"
  project = var.project_name
  network = google_compute_network.vpc.name

  direction = "INGRESS"

  source_ranges = [var.ssh_source_ranges]

  allow {
    protocol = "tcp"
    ports    = ["22"]
  }
}

resource "google_compute_firewall" "fw_frontend_to_backend_8000" {
  name    = "${var.project_name}-fw-frontend-backend-8000"
  project = var.project_name
  network = google_compute_network.vpc.name

  direction = "INGRESS"

  source_ranges = [var.frontend_cidr]

  target_tags = ["backend"]

  allow {
    protocol = "tcp"
    ports    = ["8000"]
  }
}

resource "google_compute_firewall" "fw_backend_to_database_3306" {
  name    = "${var.project_name}-fw-backend-database-3306"
  project = var.project_name
  network = google_compute_network.vpc.name

  direction = "INGRESS"

  source_ranges = [var.backend_cidr]

  target_tags = ["database"]

  allow {
    protocol = "tcp"
    ports    = ["3306"]
  }
}

resource "google_compute_router" "nat_router" {
  name    = "${var.project_name}-nat-router"
  project = var.project_name
  network = google_compute_network.vpc.self_link
  region  = var.region
}

resource "google_compute_router_nat" "nat_config" {
  name   = "${var.project_name}-nat-config"
  router = google_compute_router.nat_router.name
  region = var.region
  project = var.project_name

  nat_ip_allocate_option             = "AUTO_ONLY"
  source_subnetwork_ip_ranges_to_nat = "ALL_SUBNETWORKS_ALL_IP_RANGES"

  log_config {
    enable = false
    filter = "ALL"
  }
}