resource "google_compute_network" "vpc_network" {
  project                 = var.project_id
  name                    = "three-tier-vpc"
  auto_create_subnetworks = false
  routing_mode            = "REGIONAL"
}

resource "google_compute_subnetwork" "frontend_subnet" {
  project     = var.project_id
  name        = "frontend-subnet"
  ip_cidr_range = var.frontend_cidr
  region      = var.region
  network     = google_compute_network.vpc_network.id
}

resource "google_compute_subnetwork" "backend_subnet" {
  project     = var.project_id
  name        = "backend-subnet"
  ip_cidr_range = var.backend_cidr
  region      = var.region
  network     = google_compute_network.vpc_network.id
}

resource "google_compute_subnetwork" "database_subnet" {
  project     = var.project_id
  name        = "database-subnet"
  ip_cidr_range = var.database_cidr
  region      = var.region
  network     = google_compute_network.vpc_network.id
}

resource "google_compute_firewall" "allow_web" {
  project     = var.project_id
  name        = "allow-http-https-frontend"
  network     = google_compute_network.vpc_network.name
  direction   = "INGRESS"
  source_ranges = ["0.0.0.0/0"]
  target_tags   = ["frontend"]

  allow {
    protocol = "tcp"
    ports    = ["80", "443"]
  }
}

resource "google_compute_firewall" "allow_ssh" {
  project     = var.project_id
  name        = "allow-ssh-all"
  network     = google_compute_network.vpc_network.name
  direction   = "INGRESS"
  source_ranges = var.ssh_source_ranges
  target_tags   = ["ssh"]

  allow {
    protocol = "tcp"
    ports    = ["22"]
  }
}

resource "google_compute_firewall" "allow_frontend_to_backend" {
  project     = var.project_id
  name        = "allow-frontend-to-backend-8000"
  network     = google_compute_network.vpc_network.name
  direction   = "INGRESS"
  source_tags   = ["frontend"]
  target_tags   = ["backend"]

  allow {
    protocol = "tcp"
    ports    = ["8000"]
  }
}

resource "google_compute_firewall" "allow_backend_to_database" {
  project     = var.project_id
  name        = "allow-backend-to-database-3306"
  network     = google_compute_network.vpc_network.name
  direction   = "INGRESS"
  source_tags   = ["backend"]
  target_tags   = ["database"]

  allow {
    protocol = "tcp"
    ports    = ["3306"]
  }
}