resource "google_compute_network" "vpc" {
  name                    = "${var.project_name}-vpc"
  auto_create_subnetworks = false
}

resource "google_compute_subnetwork" "frontend" {
  name          = "${var.project_name}-frontend"
  ip_cidr_range = var.frontend_cidr
  region        = var.region
  network       = google_compute_network.vpc.id
}

resource "google_compute_subnetwork" "backend" {
  name          = "${var.project_name}-backend"
  ip_cidr_range = var.backend_cidr
  region        = var.region
  network       = google_compute_network.vpc.id
}

resource "google_compute_subnetwork" "database" {
  name          = "${var.project_name}-database"
  ip_cidr_range = var.database_cidr
  region        = var.region
  network       = google_compute_network.vpc.id
}

# HTTP/HTTPS vers frontend
resource "google_compute_firewall" "frontend_http" {
  name    = "${var.project_name}-fw-frontend-http"
  network = google_compute_network.vpc.id

  allow {
    protocol = "tcp"
    ports    = ["80", "443"]
  }

  source_ranges = ["0.0.0.0/0"]
  target_tags   = ["frontend"]
}

# SSH
resource "google_compute_firewall" "ssh" {
  name    = "${var.project_name}-fw-ssh"
  network = google_compute_network.vpc.id

  allow {
    protocol = "tcp"
    ports    = ["22"]
  }

  source_ranges = var.ssh_source_ranges
  target_tags   = ["ssh"]
}

# Frontend → Backend (8000)
resource "google_compute_firewall" "frontend_backend" {
  name    = "${var.project_name}-fw-frontend-backend"
  network = google_compute_network.vpc.id

  allow {
    protocol = "tcp"
    ports    = ["8000"]
  }

  source_tags = ["frontend"]
  target_tags = ["backend"]
}

# Backend → Database (3306)
resource "google_compute_firewall" "backend_database" {
  name    = "${var.project_name}-fw-backend-database"
  network = google_compute_network.vpc.id

  allow {
    protocol = "tcp"
    ports    = ["3306"]
  }

  source_tags = ["backend"]
  target_tags = ["database"]
}