resource "google_compute_network" "vpc" {
  name                    = "${var.projet_name}-vpc"
  project                 = var.projet_name
  auto_create_subnetworks = false
  routing_mode            = "REGIONAL"
}

resource "google_compute_subnetwork" "frontend" {
  name          = "${var.projet_name}-subnet-frontend"
  ip_cidr_range = var.frontend_cidr
  region        = var.region
  network       = google_compute_network.vpc.id
  project       = var.projet_name
}

resource "google_compute_subnetwork" "backend" {
  name          = "${var.projet_name}-subnet-backend"
  ip_cidr_range = var.backend_cidr
  region        = var.region
  network       = google_compute_network.vpc.id
  project       = var.projet_name
}

resource "google_compute_subnetwork" "database" {
  name          = "${var.projet_name}-subnet-database"
  ip_cidr_range = var.database_cidr
  region        = var.region
  network       = google_compute_network.vpc.id
  project       = var.projet_name
}

resource "google_compute_firewall" "frontend_http" {
  name    = "${var.projet_name}-allow-frontend-http"
  project = var.projet_name
  network = google_compute_network.vpc.name

  allow {
    protocol = "tcp"
    ports    = ["80", "443"]
  }

  target_tags = ["frontend"]
  direction   = "INGRESS"
  source_ranges = ["0.0.0.0/0"]
}

resource "google_compute_firewall" "ssh" {
  name    = "${var.projet_name}-allow-ssh"
  project = var.projet_name
  network = google_compute_network.vpc.name

  allow {
    protocol = "tcp"
    ports    = ["22"]
  }

  target_tags   = ["ssh"]
  direction     = "INGRESS"
  source_ranges = var.ssh_source_ranges
}

resource "google_compute_firewall" "backend_from_frontend" {
  name    = "${var.projet_name}-allow-frontend-to-backend-8000"
  project = var.projet_name
  network = google_compute_network.vpc.name

  allow {
    protocol = "tcp"
    ports    = ["8000"]
  }

  target_tags   = ["backend"]
  direction     = "INGRESS"
  source_ranges = [var.frontend_cidr]
}

resource "google_compute_firewall" "db_from_backend" {
  name    = "${var.projet_name}-allow-backend-to-db-3306"
  project = var.projet_name
  network = google_compute_network.vpc.name

  allow {
    protocol = "tcp"
    ports    = ["3306"]
  }

  target_tags   = ["database"]
  direction     = "INGRESS"
  source_ranges = [var.backend_cidr]
}